记忆：加载与存储

内存是一大排带编号的存储槽，每个槽存放一个字节（8 位）。槽的编号就是它的地址。寄存器是 CPU 的一小组快速槽位。内存大得多但更慢，它存放所有放不进寄存器的内容，比如数组和字符串。要操作内存中的值，你把它加载到寄存器，修改它，再存回去。

寄存器很少，内存很大。lw（load word）把一个字从内存复制到寄存器，sw（store word）把它复制回去。地址写作 offset(register)。

RISC-V 内存按字节寻址，所以每个字节按顺序都有自己的地址。一个字是 32 位，即 4 字节，所以要把内存指针前进 4 才能到达下一个字。这就是数组偏移量为 0、4、8 等的原因。在真实硬件上，从不是 4 的倍数的地址加载一个字可能很慢，也可能触发陷阱。本模拟器允许这样做，但你应该养成让字对齐到 4 字节的习惯。

lw t0, 0(a1) # t0 = 地址 a1 处的内存
sw t0, 4(a1) # 地址 a1+4 处的内存 = t0

在 offset(register) 中，寄存器保存的地址会加上那个小的偏移量。0(a1) 就是 a1 本身的地址，4(a1) 是它往后 4 字节。这样你无需改变基址寄存器就能访问附近的值。

用 .word（一个或多个 32 位值）或 .space N（N 个空白字节）在数据段预留具名内存。每个字占 4 字节，所以连续项位于偏移量 0、4、8 等。

.data
nums: .word 10, 20, 30, 40 # 四个字
.text
la t1, nums # t1 = 数组的地址
li t2, 4 # 计数
li t0, 0 # 累计总和
loop:
  beq t2, zero, done
  lw  t3, 0(t1) # 加载当前元素
  add t0, t0, t3 # 加到总和中
  addi t1, t1, 4 # 前进到下一个字 (4 字节)
  addi t2, t2, -1 # 剩余数减一
  j loop
done:
  mv a0, t0 # 打印总和 (100)
  li a7, 1
  ecall
  li a7, 10
  ecall

la t1, nums 把数组的地址放入 t1，t2 记录剩余 4 个元素，t0 保存累计和。每一轮中，beq t2, zero, done 在没有元素剩余时停止循环。lw t3, 0(t1) 加载 t1 指向的元素，add t0, t0, t3 把它加到和中，addi t1, t1, 4 把指针前进一个字，addi t2, t2, -1 减少计数。四个元素全部处理完后（10 + 20 + 30 + 40），done 打印 100。